VBA｜GetFolderメソッド(ファイルシステムオブジェクト)

FileSystemObjectのGetFolderメソッドは指定されたパスのフォルダオブジェクトを返します。

※ファイルシステムオブジェクト(FileSystemObject)についてはこちら

VBA｜ファイルシステムオブジェクト(FileSystemObject)でファイルやフォルダを操作する

VBAではファイルやフォルダを操作するときにつかえる便利なファイルシステムオブジェクト(FileSystemObject)の利用ができます。この記事ではファイルシステムオブジェクトをあつかうための方法や、使える機能(メソッドやプロパティ)を紹介しています。

Contents

GetFolderメソッドの構文

構文

ファイルシステムオブジェクト.GetFolder(フォルダパス(Folderpec))

GetFolderメソッドの構成要素と引数

構成要素と引数

要素／引数	必須／任意	説明
ファイルシステムオブジェクト (FSO)	必須	ファイルシステムオブジェクトを指定します。
フォルダパス (Folderpec)	必須	取得したいフォルダのパスを指定します。

その他のポイント

フォルダパス(Folderspec) に指定されたファイルが見つからなかった場合はエラーが発生します。

GetFolderメソッドをつかったサンプルマクロ

サンプルコード

  
Option Explicit

Sub ファイルシステムオブジェクト_GetFolderメソッド()

    'ファイルシステムオブジェクトを使うため準備
    '①事前バインディングの場合はVBEのツールより参照設定で「Microsoft Scripting Runtime」にチェックをしてください。
    Dim FSO As FileSystemObject
    Set FSO = New FileSystemObject

    'Folderオブジェクトを代入する変数を宣言
    Dim FolderObject As Object

    'GetFolderメソッドの使用例
    Set FolderObject = FSO.GetFolder("C:\Users\ユーザー名\Desktop\Test") 'フォルダパスを指定

    'Folderオブジェクトのプロパティを使用する
    Debug.Print "①"; FolderObject.Type 'フォルダ種別
    Debug.Print "②"; FolderObject.Name 'フォルダ名
    Debug.Print "③"; FolderObject.PATH 'フォルダパス
    Debug.Print "④"; FolderObject.DateCreated 'フォルダ作成日時
    Debug.Print "⑤"; FolderObject.DateLastAccessed 'フォルダ最終アクセス日時

    '【フォルダの中のファイル数を調べる】
    'FolderオブジェクトのFilesプロパティを代入する変数を宣言
    Dim FileCollection As Object

    'Filesコレクションを代入する
    Set FileCollection = FolderObject.Files

    'FilesコレクションのCountプロパティを利用する
    Debug.Print "⑥"; FileCollection.Count 'フォルダの中のファイルの数

    '【フォルダの中のフォルダ数を調べる】
    'FolderオブジェクトのSubFoldersコレクションを代入する変数を宣言
    Dim SubFolderCollection As Object

    'SubFoldersコレクションを代入する
    Set SubFolderCollection = FolderObject.SubFolders

    'SubFoldersコレクションのCountプロパティを利用する
    Debug.Print "⑦"; SubFolderCollection.Count 'フォルダの中のフォルダの数

End Sub

11行目

GetFolderメソッドでフォルダオブジェクトを代入するための変数FolderObjectを宣言します。

14行目

GetFolderメソッドでデスクトップの”Test”フォルダを指定しています。

17行目から21行目

Folderオブジェクトのプロパティを利用してフォルダの種別、名前、フォルダパス、作成日時、最終アクセス日時を表示しています。

25行目

GetFolderメソッドで取得したフォルダオブジェクトのFilesコレクションを代入する変数としてFileCollectionを宣言します。

28行目

Filesプロパティを利用してFileCollectionにFilesコレクションを代入しています。

31行目

FilesコレクションのCountプロパティにより、”Test”フォルダのなかのファイルの数を返しています。